REM *** FFT10.02A - Q (=2^N) POINT PFFFT (POSITIVE FREQUENCIES ONLY) ***

REM THIS PROGRAM ANALYZES FINITE DOMAIN DATA WITH FRACTIONAL FREQUENCY

REM ANALYSIS.  IT SIMULATES THE PREFORMANCE REQUIRED FOR A FREQUENCY

REM ANALYZER AND INCLUDES THE LATEST PFFFT (FFT9_04A). 8/30/96

10 SCREEN 9, 1: COLOR 15, 1: CLS 'SETUP DISPLAY SCREEN

12 QX = 2 ^ 12: QI = 2 ^ 6: WSF = 1 ' MAX & NOM ARRAY SIZE & WTNG SF CORR.

16 DIM C(2, QX), S(2, QX), KC(QX / 2), KS(QX / 2)'DIM MAX DATA AND TWIDDLE

18 PI = 3.141592653589793#: P2 = 2 * PI

20 WEXP = 6: FRACF = 1 ' WEIGHTING EXPONENT = 6 & FRACTIONAL FREQ = 1/1

24 IOFLG = 2: WTFLG = 1' GRAPHIC DISP ON, WEIGHT OFF

26 GOTO 800 ' MAIN MENU LOCATED AT LINE 800



99  REM ***********

100 REM *** FFT ***

101 REM ***********

102 T9 = TIMER' GET STARTING TIME

104 REM                *** STAGE A ***

106 FOR I = 0 TO Q2 - 1: I2 = 2 * I

108 C(T0, I2) = (C(T1, I) + C(T1, Q2 + I)) / 2

110 C(T0, I2 + 1) = (C(T1, I) - C(T1, Q2 + I)) / 2

112 NEXT I

114 REM                *** STAGE B ***

116 FOR I = 0 TO Q2 - 1 STEP 2: I2 = 2 * I: IQ2 = I + Q2

118 C(T1, I2) = (C(T0, I) + C(T0, IQ2)) / 2

120 C(T1, I2 + 1) = (C(T0, I + 1)) / 2: S(T1, I2 + 1) = (C(T0, IQ2 + 1)) / 2

122 C(T1, I2 + 2) = (C(T0, I) - C(T0, IQ2)) / 2

124 NEXT I

130 REM                *** REMAINING STAGES ***

132 FOR M = 2 TO N - 1: QT = 2 ^ (M - 1)' STAGE COUNTER

134 QT2 = 2 * QT: KT1 = 2 ^ (N - M - 1)

136 FOR I = 0 TO Q3 STEP QT2: I2 = 2 * I: K = I + Q2

138 REM * COMPUTE DIRECT COMPONENTS *

140 FOR J = 0 TO QT: JA = J + I: JA2 = J + I2: KT = J * KT1: KJ = K + J

142 C(T0, JA2) = (C(T1, JA) + C(T1, KJ) * KC(KT) - S(T1, KJ) * KS(KT)) / 2

144 S(T0, JA2) = (S(T1, JA) + C(T1, KJ) * KS(KT) + S(T1, KJ) * KC(KT)) / 2

146 NEXT J

150 REM * COMPUTE LATENT COMPONENTS *

152 FOR J = QT + 1 TO QT2: JA = I + QT2 - J: JA2 = J + I2: KT = J * KT1: KJ = K + QT2 - J

154 C(T0, JA2) = (C(T1, JA) + C(T1, KJ) * KC(KT) + S(T1, KJ) * KS(KT)) / 2

156 S(T0, JA2) = (-S(T1, JA) + C(T1, KJ) * KS(KT) - S(T1, KJ) * KC(KT)) / 2

158 NEXT J

160 NEXT I

162 T0 = 1 - T0: T1 = 1 - T0

164 NEXT M

166 T9 = TIMER - T9 ' GET ENDING TIME

170 ON IOFLG GOSUB 300, 350 ' DISPLAY SPECTRUM

172 RETURN



300 REM **** PRINT OUTPUT DATA ****

302 CLS : PRINT "FREQ     F(COS)       F(SIN)       "'PRINT HEADING

304 PRINT : PRINT

306 FOR Z = 0 TO Q4

308 GOSUB 320' PRINT DATA

310 LCTR = LCTR + 1: IF LCTR = 20 THEN LCTR = 0: INPUT A$ ' SCREEN FULL

312 NEXT Z

314 PRINT : PRINT "TIME ="; T9 ' EXECUTION TIME

316 LCTR = 0

318 RETURN

320 PRINT USING "###_    "; Z; ' PRINT 1ST COLUMN

322 PRINT USING "+##.#####_    "; C(T1, Z); S(T1, Z);

324 PRINT USING "###_    "; Z + Q4; ' PRINT 2ND COLUMN

326 PRINT USING "+##.#####_    "; C(T1, Z + Q4); S(T1, Z + Q4)

330 RETURN



349 REM ******  PLOT TRANSFORMED DATA  ******

350 CLS : X0 = 50: Y0 = 10: XSF = 500 / Q2

351 KLOG = LOG(10): YSF = LOG(ASF) / KLOG

352 LINE (X0 - 1, 50)-(X0 - 1, Y0 + 1)' DRAW Y AXIS

354 LINE (X0, Y0 + 1)-(X0 + 500, Y0 + 1)' DRAW X AXIS

356 ' * DRAW 20 DB TICKS *

358 FOR I = 1 TO 12: YSKT = YSF * 10 * LOG(1 / (10 ^ I)) / KLOG

360 LINE (X0, Y0 - YSKT)-(X0 + 500, Y0 - YSKT)

362 YDB = CINT(.3 + (Y0 - YSKT) / 13.9): IF YDB > 25 THEN 368

364 LOCATE YDB, 2: PRINT USING "###"; 10 * I;

368 NEXT I

370 LINE (X0, Y0)-(X0, Y0)' SET PEN TO ORIGIN

372 SCALE = WSF * FRACF * 2

371 FOR I = 0 TO Q2

380 YP = SCALE * SQR(C(T1, I) ^ 2 + S(T1, I) ^ 2) '  FIND RSS OF DATA POINT

381 IF YP = 0 THEN YP = -160: GOTO 384' OUT OF RANGE, SKIP

382 YP = 20 * LOG(YP) / KLOG' FIND DB VALUE

384 LINE -(X0 + XSF * I, Y0 - YSF * YP)' DRAW LINE

386 NEXT I

388 RETURN



400 REM GENERATE SINEWAVE FUNCTION

402 FOR I = 0 TO Q: C(T1, I) = 0: S(T1, I) = 0: NEXT I ' CLEAR ARRAYS

410 FOR I = 0 TO QDT ' GENERATE FUNCTION

412 C(T1, I) = SIN(F9 * 1 * K1 * I) + .00001 * SIN(F9 * 2 * K1 * I)

430 NEXT

432 IF WTFLG = 2 THEN 450 ' USE WEIGHTING FUNCTION?

440 RETURN



450 ' ****  WEIGHTING FUNCTION  ***

452 FOR I = 0 TO QDT

454 C(T1, I) = C(T1, I) * (SIN(I * PI / QDT) ^ WEXP)

456 NEXT I

458 RETURN



598 REM     *****************************

599 REM     *  GENERATE SINE COMPONENT  *

600 REM     *****************************

602 CLS : PRINT : PRINT

604 REM INPUT "PLEASE SPECIFY FREQUENCY "; F9

606 PRINT "PREPARING DATA INPUT - PLEASE WAIT!"

610 T0 = 1: T1 = 0:

612 GOSUB 400

616 GOSUB 100

618 LOCATE 2, 50: REPT = 0

619 PRINT "FREQUENCY = "; F8

620 LOCATE 22, 50: PRINT "ENTER TO CHANGE SYS: ";

622 A$ = INKEY$: IF A$ = "" THEN 622

624 IF ASC(A$) = 0 THEN GOSUB 630

626 IF REPT = 1 THEN 616

628 RETURN

630 REM HANDLE CURSOR KEYS

632 A = ASC(RIGHT$(A$, 1))

634 IF A < 75 OR A > 77 OR A = 76 THEN 646

636 IF A = 75 THEN F8 = F8 - .1

638 IF A = 77 THEN F8 = F8 + .1

640 F9 = F8 * Q / QI

642 GOSUB 400

644 REPT = 1

646 RETURN

799 REM ************************************

800 REM ***  MAIN MENU (ANALYZER SETUP)  ***

802 REM ************************************

804 CLS : LOCATE 2, 20: PRINT "ANALYZER SETUP MENU"

806 LOCATE 6, 1 ' DISPLAY MENU

820 PRINT SPC(5); "1 = ANALYZE 64    POINT ARRAY": PRINT

822 PRINT SPC(5); "2 = ANALYZE 128   POINT ARRAY": PRINT

824 PRINT SPC(5); "3 = ANALYZE 256   POINT ARRAY": PRINT

826 PRINT SPC(5); "4 = ANALYZE 512   POINT ARRAY": PRINT

828 PRINT SPC(5); "5 = ANALYZE 1024  POINT ARRAY": PRINT

829 PRINT SPC(5); "6 = ANALYZE 2048  POINT ARRAY": PRINT

830 PRINT SPC(5); "7 = ANALYZE 4096  POINT ARRAY": PRINT

831 PRINT SPC(5); "8 = CHANGE SYSTEM SETUP": PRINT

832 PRINT SPC(5); "9 = END": PRINT

834 PRINT SPC(10); "MAKE SELECTION :";

836 A$ = INKEY$: IF A$ = "" THEN 836

838 A = VAL(A$): ON A GOSUB 850, 860, 865, 870, 875, 880, 885, 900, 999

840 GOTO 804



850 N = 6: Q = 2 ^ (N)

852 Q2 = Q / 2: Q3 = Q2 - 1: Q4 = Q / 4: Q5 = Q4 - 1: Q8 = Q / 8: QI = Q / FRACF

854 F8 = 16: F9 = F8 * Q / QI: K1 = P2 / Q: QDT = Q / FRACF - 1: ASF = 630

856 FOR I = 0 TO Q2: KC(I) = COS(K1 * I): KS(I) = SIN(K1 * I): NEXT' TWIDDLE

857 GOSUB 600

858 RETURN



860 N = 7: Q = 2 ^ (N)

862 GOTO 852



865 N = 8: Q = 2 ^ (N)

867 GOTO 852



870 N = 9: Q = 2 ^ (N)

872 GOTO 852



875 N = 10: Q = 2 ^ (N)

877 GOTO 852



880 N = 11: Q = 2 ^ (N)

882 GOTO 852



885 N = 12: Q = 2 ^ (N)

887 GOTO 852





900 CLS : RTFLG = 1: PRINT "       SYSTEM SETUP MENU"

902 PRINT : PRINT "1 = DISPLAY "

904 PRINT : PRINT "2 = WEIGHTING FUNCTION"

906 PRINT : PRINT "3 = FRACTIONAL FREQUENCY"

908 PRINT : PRINT "4 = EXIT"

910 A$ = INKEY$: IF A$ = "" THEN 910

912 A = ASC(A$): IF A < 49 OR A > 52 THEN 900

914 A = A - 48: ON A GOSUB 920, 930, 970, 990

916 ON RTFLG GOTO 900, 990



920 CLS

922 PRINT "USE GRAPHIC DISPLAY (Y/N)";

924 A$ = INKEY$: IF A$ = "" THEN 924

926 IF A$ = "N" OR A$ = "n" THEN IOFLG = 1 ELSE IOFLG = 2

928 RETURN



930 CLS : PRINT "WEIGHTING FUNCTION ON (Y/N)";

932 A$ = INKEY$: IF A$ = "" THEN 932

934 IF A$ = "N" OR A$ = "n" THEN WTFLG = 1: WSF = 1: GOTO 956

936 WTFLG = 2: PRINT

938 PRINT "CHANGE WEIGHTING FUNCTION EXPONENT?"

940 A$ = INKEY$: IF A$ = "" THEN 940

942 IF A$ = "N" OR A$ = "n" THEN 952

944 PRINT "1 = SIN^2": PRINT "2 = SIN^4": PRINT "3 = SIN^6"

946 A$ = INKEY$: IF A$ = "" THEN 946

948 A = ASC(A$): IF A < 49 OR A > 51 THEN 946

950 A = A - 48: WEXP = 2 * A

952 WSF = 2: IF A = 2 THEN WSF = 8 / 3

954 IF A = 3 THEN WSF = 16 / 5



956 RETURN



970 CLS : PRINT : PRINT "SELECT FRACTIONAL FREQUENCY FOR ANALYSIS"

972 PRINT : PRINT "1 = 1/1                           4 = 1/8  "

974 PRINT "2 = 1/2                           5 = 1/16"

976 PRINT "3 = 1/4                           6 = 1/32"

978 A$ = INKEY$: IF A$ = "" THEN 978

980 A = ASC(A$): IF A < 49 OR A > 54 THEN 978

982 A = A - 49: FRACF = 2 ^ A

988 RETURN



990 RTFLG = 2: RETURN



999 END



1000  REM *   KEY IDENTIFIER   *

A$ = INKEY$: IF A$ = "" THEN 1000

PRINT A$, "ASC = "; ASC(A$);

IF ASC(A$) = 0 THEN PRINT ASC(RIGHT$(A$, 1));

PRINT

GOTO 1000



